Belgian Amiga Club - ADF Collection/BS1 part 05.zip/BS1 part 5/Cinemorph.adf/Install

Text File | 1992-09-01 | 5KB | 193 lines

; Installer script for Cinemorph

(
   ; Ask where to install it...
   (set @default-dest
      (askdir
         (prompt "Select or create the directory where you would "
                 "like to install Cinemorph.")
         (help "Cinemorph and all necessary files will be installed "
               "in the directory of your choice.  You may wish to "
               "create a new directory for Cinemorph by using the "
               "'Make New Drawer' gadget.")
         (default "RAM:")
      )
   )

   ; Ask which version(s) to install...
   (set todo
      (askoptions
         (prompt
            "Choose which version of Cinemorph you would like "
            "to install:")
         (help "Two versions of Cinemorph are provided.  The "
               "accelerated version (Cinemorph.FP) requires "
               "a 68020/68881 or greater machine to function. "
               "If you have such an accelerator, the accelerated "
               "version of Cinemorph is considerably faster.")
         (choices
            "Cinemorph for Non-Accelerated Machines"
            "Cinemorph for Accelerated Machines")
      )
   )

   (if (= todo 0)
      (abort "Nothing to do.")
   )

   (complete 0)

   ; Copy help file...
   (copyfiles
      (prompt "")
      (help "")
      (source ":Cinemorph/Cinemorph.guide")
      (dest @default-dest)
   )

   (complete 10)

   ; Copy 68000 version...
   (if (<> todo 2)
      (
         (copyfiles
            (prompt "")
            (help "")
            (source ":Cinemorph/Cinemorph")
            (dest @default-dest)
         )
         (copyfiles
            (prompt "")
            (help "")
            (source ":Cinemorph/Cinemorph.info")
            (dest @default-dest)
         )
      )
   )

   (complete 20)

   ; Copy FP version...
   (if (<> todo 1)
      (
         (copyfiles
            (prompt "")
            (help "")
            (source ":Cinemorph/Cinemorph.FP")
            (dest @default-dest)
         )
         (copyfiles
            (prompt "")
            (help "")
            (source ":Cinemorph/Cinemorph.FP.info")
            (dest @default-dest)
         )
      )
   )

   (complete 30)
   (working "Checking for required libraries...")

   ; Copy all the libraries...
   (copylib
      (prompt "Copying iffparse.library to LIBS:")
      (help "This library is required to load any IFF images.")
      (source ":libs/iffparse.library")
      (dest "LIBS:")
   )

   (complete 40)

   (copylib
      (prompt "Copying amigaguide.library to LIBS:")
      (help "This library is required to use the online help "
            "features of Cinemorph.")
      (source ":libs/amigaguide.library")
      (dest "LIBS:")
   )

   (complete 50)

   (copylib
      (prompt "Req.library:  Installation of this library is only "
              "required if you plan to run Cinemorph under Workbench 1.3. "
              "It is not needed under Workbench 2.0 or greater.")
      (help "Select 'Proceed with Copy' to copy the indicated library "
            "to your LIBS: directory, or 'Skip This Part' if you do "
            "not need the library.")
      (source ":libs/req.library")
      (dest "LIBS:")
      (confirm)
   )

   (complete 60)

   (copylib
      (prompt "Dctv.library:  Installation of this library is only "
              "required if you intend to render images directly to "
              "DCTV format.")
      (help "Select 'Proceed with Copy' to copy the indicated library "
            "to your LIBS: directory, or 'Skip This Part' if you do "
            "not need the library.")
      (source ":libs/dctv.library")
      (dest "LIBS:")
      (confirm)
   )

   (complete 70)

   (copylib
      (prompt "Hame.library:  Installation of this library is only "
              "required if you intend to render images directly to "
              "HAM-E format.  If you choose to install this library, "
              "you must also install Renderhame.library.")
      (help "Select 'Proceed with Copy' to copy the indicated library "
            "to your LIBS: directory, or 'Skip This Part' if you do "
            "not need the library.")
      (source ":libs/hame.library")
      (dest "LIBS:")
      (confirm)
   )

   (complete 80)

   (copylib
      (prompt "Renderhame.library:  Installation of this library is only "
              "required if you intend to render images directly to "
              "HAM-E format.  You must install this library if you "
              "chose to install Hame.library.")
      (help "Select 'Proceed with Copy' to copy the indicated library "
            "to your LIBS: directory, or 'Skip This Part' if you do "
            "not need the library.")
      (source ":libs/renderhame.library")
      (dest "LIBS:")
      (confirm)
   )

   (complete 90)

   (if
      (askbool
         (prompt
            "Do you want to copy over the sample project files "
            "and images?")
         (help "The sample projects and images may be used to "
               "help get you started in Cinemorph.  They are the "
               "ones referenced by the tutorials in the manual.")
         (default 1)
      )
      (
         (copyfiles
            (prompt "")
            (help "")
            (source ":Samples")
            (dest (tackon @default-dest "Samples"))
            (all)
         )
      )
   )

   (complete 100)
)